TAKE · Excel · คลังสูตร 9Expert

TAKE คืออะไร

ดึงจำนวนแถวหรือคอลัมน์ที่ต้องการจากต้นหรือท้ายของตาราง ใช้ทำ Top 3 หรือดูรายการล่าสุด

ใช้เมื่อไหร่

ทำรายงาน Top 3 หรือ Top 10 ที่อัปเดตเองเมื่อยอดเปลี่ยน
ดูรายการล่าสุด 3–5 รายการจากตารางที่เรียงตามวันที่
ตัดผลลัพธ์ของ SORT หรือ FILTER ให้เหลือเฉพาะแถวหรือคอลัมน์ที่ต้องการ

รูปแบบสูตร

=TAKE(array, rows, [columns])

Argument แต่ละตัว

ชี้ที่ argument ในรูปแบบสูตรด้านบนเพื่อไฮไลต์แถวนั้น

Argument	จำเป็นไหม	ความหมาย
array	จำเป็น	ช่วงหรือ array ที่ต้องการดึงแถวหรือคอลัมน์
rows	จำเป็น	จำนวนแถว ค่าบวกนับจากบน ค่าติดลบนับจากท้าย (เว้นว่างได้เมื่อใส่ columns)
[columns]	ไม่บังคับ	จำนวนคอลัมน์ ค่าบวกนับจากซ้าย ค่าติดลบนับจากขวา ถ้าไม่ใส่ได้ทุกคอลัมน์

ลองเลย: ตัวอย่างที่เปลี่ยนค่าได้

ข้อมูลชุดเดียวกับไฟล์ฝึก เปลี่ยนค่าในช่องกรอก หรือคลิกตัวเลขในตารางเพื่อแก้ แล้วดูผลลัพธ์เปลี่ยนทันที กดถัดไปเพื่อดูว่า Excel คิดทีละขั้นอย่างไร สีของช่วงในตารางตรงกับสีในสูตร

SORT เรียงทั้งตารางตามยอดสุทธิจากมากไปน้อยก่อน แล้ว TAKE เอาเฉพาะจำนวนแถวแรกตาม I4

A17

=TAKE(SORT(A5:D14,4,-1),I4)

คอลัมน์ที่ใช้เรียง (sort_index) 4 คือคอลัมน์ที่ 4 ของ A5:D14 = คอลัมน์ D "ยอดสุทธิ (บาท)"

แถว	A	B	C	D
4	เลขที่คำสั่งซื้อ	วันที่	พนักงานขาย	ยอดสุทธิ (บาท)
5	SF-2025-0734	1/12/2025	สุภาพร หงษ์ทอง	355,320
6	SF-2025-0738	2/12/2025	กมลชนก พงษ์พานิช	1,235,098
7	SF-2025-0739	3/12/2025	นันทิดา กิจเจริญ	22,878
8	SF-2025-0741	4/12/2025	นันทิดา กิจเจริญ	298,740
9	SF-2025-0744	6/12/2025	สุภาพร หงษ์ทอง	269,705
10	SF-2025-0750	8/12/2025	กมลชนก พงษ์พานิช	522,200
11	SF-2025-0756	9/12/2025	สุภาพร หงษ์ทอง	1,057,572
12	SF-2025-0760	11/12/2025	กมลชนก พงษ์พานิช	1,049,152
13	SF-2025-0774	15/12/2025	นันทิดา กิจเจริญ	334,720
14	SF-2025-0784	19/12/2025	กมลชนก พงษ์พานิช	289,275
15	ผลลัพธ์จากสูตรในช่อง A17 · spill ลงมาเอง
16	เลขที่คำสั่งซื้อ	วันที่	พนักงานขาย	ยอดสุทธิ (บาท)
17	SF-2025-0738	2/12/2025	กมลชนก พงษ์พานิช	1,235,098
18	SF-2025-0756	9/12/2025	สุภาพร หงษ์ทอง	1,057,572
19	SF-2025-0760	11/12/2025	กมลชนก พงษ์พานิช	1,049,152
20
21
22
23
24

A5:D14

ช่องกรอกและผลลัพธ์

จำนวนอันดับ (rows) I4

สูตรที่ A17 (ผลลัพธ์ spill)

ขั้นตอนการคำนวณ (5)

ผลลัพธ์ในกรอบเส้นประมาจากสูตรเดียวในช่องสีเขียวมะนาว คลิกช่องไหนในผลลัพธ์ก็ได้เพื่อดูสูตร · แก้ข้อมูลด้านบนแล้วผลลัพธ์จะขยายหรือหดเอง · แก้สูตรได้ที่แถบสูตร หรือพิมพ์ = ในช่องว่าง

100%

ข้อมูลสมมติของสยามเฟรช ชุดเดียวกับชีต “1 Top 3” ในไฟล์ฝึก (ปี ค.ศ.)

อ่านสูตร: SORT(A5:D14,4,-1) เรียงตามคอลัมน์ที่ 4 (ยอดสุทธิ) จากมากไปน้อย แล้ว TAKE(…,3) เอา 3 แถวแรก
เลือก I4 เป็น 5 จะได้ Top 5 ผลลัพธ์ยืดลงมาเอง
ต้องเรียงก่อนแล้วค่อย TAKE ถ้าสลับกัน จะได้แค่ 3 แถวแรกของตารางเดิมมาเรียง ไม่ใช่ 3 ยอดสูงสุด

ตัวอย่างทั้งหมด 4 แบบ

1Top 3 คำสั่งซื้อยอดสูงสุด · SORT เรียงทั้งตารางตามยอดสุทธิจากมากไปน้อยก่อน แล้ว TAKE เอาเฉพาะจำนวนแถวแรกตาม I4
23 คำสั่งซื้อล่าสุดด้วย rows ติดลบ · ตารางเรียงตามวันที่จากเก่าไปใหม่ แถวท้ายสุดจึงเป็นรายการล่าสุด rows ติดลบนับจากท้ายตาราง
3เลือกแถวและคอลัมน์พร้อมกัน · ทำประกาศรางวัลบริการยอดเยี่ยม: SORT เรียงตามคะแนนลูกค้า แล้ว TAKE(…,I4,2) เอาแถวแรกตาม I4 และแค่ 2 คอลัมน์แรก คือชื่อกับภูมิภาค
43 คำสั่งซื้อล่าสุดของพนักงานที่เลือก · FILTER ดึงเฉพาะคำสั่งซื้อของพนักงานใน I4 แล้ว TAKE(…,-3) เอา 3 รายการท้ายสุด

ข้อผิดพลาดที่พบบ่อย

#CALC!สาเหตุ: rows หรือ columns เป็น 0 ได้ array ว่างแก้: ใส่จำนวนที่ไม่ใช่ 0

Top 3 ไม่ใช่ยอดสูงสุดสาเหตุ: ใช้ TAKE ก่อนเรียง ได้แค่ 3 แถวแรกของตารางเดิมแก้: ครอบ SORT หรือ SORTBY ไว้ด้านในก่อน แล้วค่อย TAKE

#SPILL!สาเหตุ: มีข้อมูลขวางพื้นที่ผลลัพธ์แก้: ลบหรือย้ายข้อมูลที่ขวาง

#NAME?สาเหตุ: เปิดใน Excel 2016, 2019 หรือ 2021แก้: ใช้สูตรในชีต Excel 2016-2021

เคล็ดลับจากห้องเรียน

Top N ที่เปลี่ยนจำนวนได้: ใส่ rows เป็นช่อง เช่น =TAKE(SORT(A5:D14,4,-1),I4)

ขอจำนวนแถวมากกว่าที่มี TAKE คืนเท่าที่มี ไม่เกิด Error

ต้องการตัดแถวออกแทนการเลือกเก็บ ใช้ DROP เช่น =DROP(A5:D14,1) ตัดแถวแรกทิ้ง

ใช้กับ Excel ของคุณได้ไหม

เวอร์ชัน	Excel 2016	Excel 2019	Excel 2021	Excel 2024	Microsoft 365
TAKE

ใช้ Excel 2016, 2019 หรือ 2021 ให้ใช้สูตรเหล่านี้แทน ได้ผลเท่ากับตัวอย่างที่ระบุ และมีในชีต “Excel 2016-2021” ของไฟล์ฝึก ต่างจาก TAKE ตรงที่ผลลัพธ์ไม่ spill เอง ต้องลากสูตรลงให้พอกับจำนวนรายการ (ไม่ต้องกด Ctrl + Shift + Enter)

แทนตัวอย่าง	สูตรทางเลือก
ตัวอย่าง 1 ยอด Top 3	=LARGE($D$5:$D$14,ROWS($A$5:A5)) แล้วลากลง 3 แถว
ตัวอย่าง 1 เลขที่คำสั่งซื้อของยอดนั้น	=INDEX($A$5:$A$14,MATCH(H5,$D$5:$D$14,0))
ตัวอย่าง 2 3 รายการล่าสุด	=INDEX($A$5:$A$14,ROWS($A$5:$A$14)-3+ROWS($A$5:A5)) แล้วลากลง 3 แถว

เลือกวิธีให้ถูกงาน

วิธี	ใช้เมื่อ	ตัวอย่าง
TAKE	เอาจำนวนแถวหรือคอลัมน์จากต้นหรือท้าย (2024 ขึ้นไป)	=TAKE(SORT(A5:D14,4,-1),3)
LARGE + INDEX/MATCH	Top N ได้ทุกเวอร์ชัน (ลากสูตรลง)	=LARGE($D$5:$D$14,ROWS($A$5:A5))
FILTER	เลือกแถวตามเงื่อนไข ไม่ใช่ตามตำแหน่ง	=FILTER(A5:D14,D5:D14>=1000000)
XLOOKUP ค้นจากล่างขึ้นบน	ต้องการแค่รายการล่าสุดรายการเดียว	=XLOOKUP(I4,C5:C14,A5:A14,,0,-1)